La función SUMIF en Google Sheets se usa para sumar los números en un rango basado en una condición. La función SUMIF está básicamente diseñada para sumar los números basados en una condición a cumplir. Este tutorial explicará cómo utilizar esta función en Google Sheets.

Cómo utilizar SUMIF en Google Sheets

SUMIF tiene dos partes, SUM y IF. Si un rango de celdas cumple la condición, entonces esta función suma los números relacionados con esa condición. La sintaxis de la función SUMIF en Google Sheets es la misma que la de Excel;

=SUMIF(range, criterion, )

Donde,

rango: Es un rango de celdas que se comprueba con un criterio

criterio: Es una condición que debe cumplirse. Puede contener un valor (número, texto, fecha), una expresión, un operador lógico, un carácter comodín, una referencia de celda u otra función.

rango_suma: Es un rango de celdas para sumar los números en los que se cumple una condición.

Reglas para SUMIF

Hay algunas reglas a seguir mientras se utiliza la función SUMIF correctamente;

• La función SUMIF no distingue entre mayúsculas y minúsculas.

• El tamaño del rango y el rango_suma deben ser iguales

• El rango y el rango_suma pueden ser iguales si se comprueba un rango numérico con un número como criterio.

• Si el criterio contiene un texto, una fecha, una expresión, un operador lógico y un comodín, entonces debe ir entre comillas dobles, como «camiseta», «>5», «*»

• Si el criterio es un número referencia de celda u otra función, entonces no debe ir entre comillas dobles como B1 o Today()

• Si el criterio contiene tanto el operador lógico como la referencia de celda u otra función, entonces deben unirse utilizando un ampersand (&), como «>»&B2, o «>»&Today()

Cuando se introduce la función SUMIF en Google Sheets, aparece un cuadro de autosugestión que contiene la sintaxis, el ejemplo, el resumen relacionado con la función SUMIF y la explicación de cada parte de la función, como se muestra a continuación.

En este artículo, aprenderá a utilizar la función SUMIF en Google Sheets en diferentes casos de criterio con ejemplos.

Función SUMIF con criterios de texto

Si desea sumar los números en el rango de celdas que tienen un valor de texto específico en un rango de celdas paralelo, otra columna y la misma fila, suministrado como criterio.

Por ejemplo, usted tiene un conjunto de datos de información de pedidos de ventas para varios productos, y desea sumar las cantidades de pedidos para el producto «Apple» como el criterio. Así que el criterio se puede suministrar en la función SUMIF como valor de texto entre comillas dobles o como referencia de celda sin comillas dobles, como;

=SUMIF(B2:B20,"Apple",D2:D20)

O

=SUMIF(B2:B20,H2,D2:D20)

Aquí,

B2:B20 es el rango de celdas

«Apple» o H2 es el criterio como valor de texto o referencia de celda

D2:D20 es rango_suma de celdas

Función SUMIF con criterios numéricos

Si quieres sumar los números que cumplen cierto criterio como se especifica en la función SUMIF en Google Sheets, utilizando operadores de comparación, como mayor que (>), menor que (<), mayor que igual a (>=), menor que igual a (<=) o No igual a (<>).

Suponga que quiere sumar todos los importes de los pedidos que sean mayores que iguales a 5.000 dólares. En este caso, el rango y sum_range son los mismos, ya que los importes de los pedidos aparecen en el mismo rango y los criterios también se aplican en el mismo rango. En este caso, la función SUMIF se puede aplicar de una de estas maneras;

=SUMIF(D2:D20,">=5000",D2:D20)

O

=SUMIF(D2:D20,">="&H2,D2:D20)

Como puede ver la expresión del criterio se suministra entre comillas dobles en la función SUMIF, como «>=5000», pero si el criterio se suministra como expresión y referencia de celda, entonces se unen por un ampersand (&), como «>=»&H2.

Función SUMIF con criterios de Fecha

Puede sumar los números basados en criterios de fecha utilizando cualquiera de los operadores de comparación. La fecha debe suministrarse entre comillas dobles en un formato comprensible para Google Sheets, o la fecha debe suministrarse como referencia de celda sin comillas dobles, o la fecha debe suministrarse utilizando una función de fecha como DATE() o TODAY().

Supongamos que quieres sumar los importes de los pedidos que son mayores que iguales a (>=) una fecha criterio, digamos el 1/7/2018, entonces puedes sumar esos importes usando la función SUMIF de cualquiera de las siguientes maneras;

=SUMIF(E2:E20,">=7/1/2018",D2:D20)

O

=SUMIF(E2:E20,">="&H2,D2:D20)

O

=SUMIF(E2:E20,">="&Date(2018,7,1),D2:D20)

Función SUMIF con criterios de celdas en blanco o no

Puede sumar los números basándose en los criterios en los que las celdas están en blanco o no en un rango de celdas utilizando la función SUMIF en Google Sheets.

Supongamos que en su conjunto de datos algunos de los pedidos no tienen fecha de entrega mencionada, por lo que desea sumar los importes de los pedidos basándose en los criterios donde se menciona la fecha de entrega (no en blanco), y donde no se menciona la fecha de entrega (en blanco).

• Función SUMIF con criterios de celdas en blancoEsta fórmula SUMIF sumará los importes de los pedidos donde no se menciona la fecha de entrega en el rango. El criterio se suministra como comillas dobles sin ningún espacio intermedio, como «».

  =SUMIF(E2:E20,"",D2:D20)

  

• Función SUMIF con criterios de celdas no en blancoEsta fórmula SUMIF sumará los importes de los pedidos en los que la fecha de entrega se menciona en el rango. El criterio se suministra utilizando el operador de comparación No igual a (<>) entre comillas dobles, como «<>», significa que las celdas no están en blanco. Esto excluye las cantidades en las que las fechas de entrega están en blanco.

  =SUMIF(E2:E20,"<>",D2:D20)

  

¿Todavía necesita ayuda con el formato de Excel o tiene otras preguntas sobre Excel? Conéctese con un experto en Excel en vivo aquí para obtener ayuda 1 a 1. Su primera sesión es siempre gratuita.